# La tour de Babel : traduire son logiciel

Dans ce chapitre, vous apprendrez à traduire un projet dans une autre langue. Vous découvrirez aussi que la première langue étrangère pour Lazarus est… le français.

Le programmeur qui souhaite adapter un logiciel à une autre langue pensera peut-être qu’il suffit de traduire les termes à afficher et de présenter cette traduction à l’utilisateur final. Pour lui, la tâche paraît triviale. Et pourtant…

Ce programmeur naïf aura certes prévu une série de messages et pensé à les regrouper dans une unité particulière afin d’éviter de se perdre dans le code source, mais il aura aussi complété des propriétés depuis l’inspecteur d’objet (*Hint* et *Caption* par exemple), fait appel à des unités tierces qui elles-mêmes renvoient des messages (ne serait-ce que ceux de la LCL) et prévu la récupération de données depuis des fichiers ou un clavier. Les chaînes de caractères affichées sont en effet d’origines diverses : elles peuvent aussi bien provenir du code du programme, des fiches créées, des unités utilisées que de conditions extérieures. Dans ce contexte, comment se mettre à l’abri d’oublis, d’erreurs ou d’incohérences ?

De plus, les langues n’entretiennent pas des relations bijectives : les caractères employés, la ponctuation, la syntaxe, les accords (le genre et le nombre), l’emploi des modes et des temps, les habitudes de formulation, même la signification des couleurs sont quelques-uns des aspects qui révèlent qu’une langue renvoie à un système complexe attaché à une culture particulière.

On pourrait ainsi multiplier les exemples de complications :

* L’anglais est une langue compacte si on la compare aux autres langues : il faut en tenir compte pour la largeur des légendes des composants utilisés ;
* Les langues à idéogrammes ignorent les abréviations ;
* Les majuscules ont un sens particulier en allemand ;
* La notion de pluriel est dépendante de la langue utilisée (Anglais: “*If the length of S is already equal to N, then no characters* are *added*.” – Français : « Si la longueur de S est déjà égale à N, aucun caractère n’*est* ajouté. ») ;
* Le mois d’une date en anglais est donné avant le jour, contrairement au français ;
* …

Dans le cadre de ce chapitre, afin de ne pas lui donner une ampleur démesurée, ne sera abordée que la traduction du point de vue du programmeur : comment faire pour qu’un logiciel s’adapte au mieux à une autre langue ? Mais il faudra que vous gardiez à l’esprit ce qui précède avant de vous lancer dans l’internationalisation d’un travail !


Si vous êtes tenté d’ignorer ce chapitre en pensant limiter votre production à la langue française, vous êtes invité à en lire au moins la première partie. En effet, Lazarus et Free Pascal sont des outils conçus en anglais pour un public anglophone. Les difficultés commencent dès lors qu’un projet envisage d’utiliser une autre langue que celle d’origine.

## Un programme français… en anglais


Pour vous en persuader, examinez le comportement d’un programme aussi élémentaire que celui-ci :

* Créez un nouveau projet ;
* Modifiez la légende de la fiche (*Caption*) en la faisant passer de ***Form1*** à ***En français 1…***;
* Déposez un bouton (*TButton*) sur la fiche proposée ;
* Modifiez la légende de ce bouton (*Caption*) en la faisant passer de ***Button1*** à ***Bouton*** ;
* Déposez un bouton avec glyphe (*TBitBtn*) sur la même fiche ;
* Modifiez sa propriété de type (*Kind*) en la faisant passer de ***bkCustom*** à ***bkYes***.

Voici l’aspect, à la conception, de votre préparation :



Compilez à présent votre application et lancez son exécution. Voici ce que vous obtiendrez :




Vous serez sans doute tenté de croire que la transformation du **Oui** en **Yes** pour le composant *TBitBtn* est un bogue de Lazarus puisque le composant *TButton* ne semble pas souffrir de la même tare. Cependant, avant de vous ruer sur la rubrique *Bugtracker* du site de Lazarus, il est de nouveau conseillé de lire la suite. Ce comportement apparemment aberrant s’explique si l’on comprend comment fonctionne le système de traduction.

### Un peu de bricolage pour traduire

Une première manière de contourner le problème rencontré serait de modifier manuellement la valeur de la propriété en cause, ici *Caption*. En effet, si vous changez cette valeur depuis l’inspecteur d’objet, le comportement correspondra à celui qui était attendu :


* Modifiez la valeur de la légende (*Caption*) en la passant de ***&Oui*** à ***&Oui-oui*** ;
* Compilez le programme ;
* Lancez son exécution.

Vous obtiendrez cet écran :




Que s’est-il passé ? Pour le comprendre, il faut examiner les fichiers **LFM** qui contiennent la description des fiches. Comme ce sont de simples fichiers textes, des outils tels que **Notepad++** pour Windows ou **gEdit** pour Linux sont tout à fait adaptés.

Dans la première version du programme, on lit ceci :



On voit que le *BitBtn* affiche la légende par défaut : c’est ce qu’indique la ligne ***DefaultCaption = True***.

L’affichage de la version modifiée donne ceci :



Cette fois-ci, la ligne relevée a disparu, mais une autre ligne a fait son apparition : ***Caption = ‘&Oui-oui’***. C’est elle qui assure que le message sera bien traduit à l’exécution.

Un problème secondaire surgit avec cette solution : la chaîne par défaut est finalement la seule qui ne sera jamais affichée ! Dès que vous la proposez, elle est ôtée du fichier **LFM**.

Mais revenons à notre question initiale : que s’est-il passé ? Afin d’éviter d’encombrer le fichier **LFM** de données inutiles, **l’EDI n’enregistre que les valeurs des propriétés qui diffèrent de leur valeur par défaut**.

En modifiant le libellé manuellement, vous avez forcé Lazarus à stocker la nouvelle valeur dans le fichier **LFM** qui accompagne la fiche en cause. De même, en inversant la valeur de la propriété *DefaultCaption*, vous avez forcé l’affichage de la propriété *Caption* telle qu’elle apparaît dans l’inspecteur d’objet et non telle qu’elle est enregistrée par défaut dans la LCL. Autrement dit, si vous souhaitez qu’une propriété ait une valeur différente de celle par défaut, assurez-vous que le fichier **LFM** l’ait correctement enregistrée.

Souvenez-vous surtout que les valeurs par défaut sont celles définies au sein des unités employées, en particulier de la LCL. Ces valeurs sont essentiellement définies dans le constructeur *Create* des classes, en accord avec l’interface qui emploie le mot réservé *default* suivi de la valeur par défaut s’il s’agit de propriétés aux valeurs discrètes.

En fait, avec le composant *TBitBtn*, on aurait obtenu le même affichage en changeant la valeur de *DefaultCaption* de ***True*** à ***False***. Cette seconde solution serait idéale si elle était indépendante du composant utilisé, mais cette propriété n’est présente que pour les descendants de *TCustomBitBtn* !

### Une solution plus générale

Vous pourriez vous satisfaire des deux premières solutions pour les propriétés accessibles en écriture. Malheureusement, de nombreux messages ne sont pas de ce type : certaines propriétés (comme le nom des couleurs) et la plupart des messages d’erreur sont hors de portée des unités créées.

Lazarus vient alors à votre rescousse en intégrant un système de traduction complet et automatique.

Pour illustrer le mécanisme mis en œuvre, procédez comme suit :

* Créez un nouveau projet ;
* Dans *Projet* → *Options du projet* → *i18n*, cochez *i18n* et *Créer/mettre à jour le fichier « .po » en enregistrant le fichier « .lfm »* ;
* Modifiez la légende de la fiche (*Caption*) en la faisant passer de ***Form1*** à ***En français 3…***;
* Déposez un bouton avec glyphe (*TBitBtn*) sur la même fiche ;
* Modifiez sa propriété de type (*Kind*) en la faisant passer de ***bkCustom*** à ***bkYes***;
* Enregistrez ce projet dans le répertoire de votre choix sous le nom *project3.lpr* ;
* Ouvrez depuis le navigateur le répertoire utilisé ;
* Créez un sous-répertoire que vous baptiserez *languages* (ce nom a son importance !) ;
* Déplacez le fichier *projet3.po* apparu dans le dossier du projet dans le répertoire *languages* (si ce fichier est introuvable, déplacez légèrement la fiche principale et enregistrez de nouveau le projet) ;
* Copiez le fichier *lclstrconsts.fr.po* depuis son répertoire d’origine jusqu’au répertoire *languages* que vous venez de créer (l’emplacement de *lclstrconsts.fr.po* est le sous-répertoire *lcl/languages* du répertoire d’installation de Lazarus) ;
* Éditez le fichier du projet *project3.lpr* grâce à l’inspecteur de projet (il apparaît lorsqu’on choisit *Projet* → *Inspecteur de projet* dans le menu principal de l’EDI) ;
* Ajoutez l’unité **D*efaultTranslator*** à la clause *uses* du programme :

program project3;

{$mode objfpc}{$H+}

uses

{$IFDEF UNIX}{$IFDEF UseCThreads}

cthreads,

{$ENDIF}{$ENDIF}

Interfaces, // this includes the LCL widgetset

Forms, unit3

{ you can add units after this }

, DefaultTranslator; // 🡸 unité ajoutée

* Compilez et exécutez le programme.

Cette fois-ci, sans avoir rien modifié des propriétés à la conception, le programme traduit correctement la légende du bouton. Vous êtes toutefois en droit de vous dire que les moyens mis en œuvre sont disproportionnés par rapport aux résultats ! Pour vous rassurer, nous allons ci-après expliquer l’intérêt de l’ensemble puis son fonctionnement.

### Intérêt de ne pas bricoler la traduction

Vous avez à présent trois solutions à votre disposition :

* La modification manuelle de certains messages ;
* La modification de certaines propriétés susceptibles de modifier l’affichage ;
* L’utilisation du système automatique intégré de Lazarus *via* l’unité ***DefaultTranslator***.

Si les deux premières sont légères, la dernière est de loin celle recommandée, car elle fonctionne automatiquement pour tous les messages des unités du projet. Elle évite par conséquent de parcourir les unités et les fichiers **LFM** à la recherche de chaînes à traduire, avec le risque d’en oublier ! Enfin, elle est la seule à pouvoir traiter les messages inaccessibles depuis l’EDI.

En guise de démonstration, voici un nouveau programme très simple :

* Créez un nouveau projet ;
* Dans *Projet* → *Options du projet* → *i18n*, cochez *i18n* et *Créer/mettre à jour le fichier « .po » en enregistrant le fichier « .lfm »* ;
* Modifiez la légende de la fiche (*Caption*) en la faisant passer de ***Form1*** à ***En français 4…***;
* Déposez un composant TColorListBox sur la fiche principale ;
* Déposez un composant TButton sur la même fiche ;
* Modifiez la légende du bouton (*Caption*) en la faisant passer de ***Button1*** à ***Joli !***;
* Créez un événement OnClick pour le bouton et entrez le code suivant dans la partie implementation de la fiche :

resourcestring

// chaînes de ressources pour leur future traduction

RS\_Pretty = 'Joli !';

RS\_NotPretty = 'Pas joli !';

{$R \*.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);

begin

if cbPrettyNames in ColorListBox1.Style then

begin

// propriété exclue

ColorListBox1.Style := ColorListBox1.Style - [cbPrettyNames];

Button1.Caption := RS\_Pretty;

end

else

begin

// propriété incluse

ColorListBox1.Style := ColorListBox1.Style + [cbPrettyNames];


Button1.Caption := RS\_NotPretty;

end;


end;

La procédure introduite permet de modifier l’affichage du bouton en fonction de la propriété Style de de la TColorListBox. L’option qui alterne est cbPrettyNames : si elle est incluse dans le style, le composant fait appel à la LCL pour afficher le nom en clair des couleurs et non leur codage interne.

À cette étape, si vous lancez l’exécution du programme et que vous cliquez sur le bouton, vous obtiendrez des noms en anglais :



En ajoutant la même unité ***DefaultTranslator*** à la clause uses du programme principal et les mêmes fichiers **PO** dans un sous-répertoire *languages* du répertoire de l’application, les noms de couleurs seront traduits :



En revanche, le codage des couleurs n’est pas affecté par la traduction : par exemple, clBlue affiche **Blue** en anglais et **Bleu** en français. Si vous cliquez de nouveau sur le bouton, les codes seront affichés tout simplement. Ce fonctionnement est bien celui désiré : pour l’utilisateur final, seul le nom des couleurs importe ; pour le programmeur, c’est celui des codes associés à ces couleurs.

Ce qu’il faut retenir de cet exemple très simple, c’est que des propriétés inaccessibles directement depuis l’EDI, comme ici le nom des couleurs, peuvent être traduites grâce à un mécanisme automatique.

Par la même occasion, les messages d’exception le sont aussi. Pour vous en assurer, complétez le code de la procédure Button1Click ainsi :

procedure TForm1.Button1Click(Sender: TObject);

var

I, J: Integer;

begin

I := 2;

J := I - I;

Button1.Caption:= IntToStr(I div J); // oups…

// le reste ne change pas…

if cbPrettyNames in ColorListBox1.Style then

{…}

Lors du clic sur le bouton, une exception va être levée, car vous tenterez de diviser un nombre par 0. Avec l’unité ***DefaultTranslator***, le message sera affiché en français. Si vous retirez l’unité de la clause uses du programme principal, le message sera en anglais. La solution adoptée pour la traduction est par conséquent très puissante : tout ce qui est du ressort de la LCL est traduit !

### Fonctionnement de la solution générale

Comme le monde de l’informatique est étranger à la magie, l’apparent miracle de la traduction du texte a évidemment une explication rationnelle.

Le fait d’activer l’option **i18n** d’un projet indique au compilateur Free Pascal qu’il va devoir s’occuper de l’internationalisation du projet. **i18n** n’est qu’une abréviation d’*internationalization* : le **i** du début, les **18** lettres du mot et le **n** de la fin. En cochant la création et la mise à jour de fichiers **PO** à l’enregistrement des fichiers **LFM**, vous forcez Lazarus à produire des fichiers de ressources particuliers **LRT** pour chaque fiche lors de son enregistrement. Au cours de la compilation, Lazarus va rassembler ces fichiers de ressources en un seul fichier qui portera le nom du projet avec le suffixe **PO**. Ce fichier final contiendra toutes les chaînes à traduire définies par le projet. Nous détaillerons son contenu quand nous aborderons les traductions multilingues.

L’étape suivante consiste à inclure ***DefaultTranslator*** dans la clause *uses* du programme principal. Cette unité est rudimentaire, car elle se contente d’utiliser une autre unité (***LCLTranslator***) et d’exécuter dans sa section *initialization* une simple ligne :

SetDefaultLang('', '', false);

Cette procédure travaille pour l’essentiel ainsi :

* Elle recherche un éventuel fichier **PO** portant le nom du projet adapté à la langue du système (pour nous, le français) : *projet3.fr.po* ;
* En cas de réussite, elle convertit les chaînes qu’il contient ;
* En cas de nouveau succès, elle recherche la version adaptée du fichier *lclstrconsts.po* (dans notre cas *lclstrconsts.fr.po*) pour convertir toutes ses chaînes.

Le premier travail s’effectue grâce à la fonction *FindLocaleFileName* de l’unité ***LCLTranslator***. Cette fonction cherche le fichier **PO** adapté à partir d’une série de répertoires standards et dans cet ordre : *languages* (celui que nous avons utilisé), *locale*, *locale\LC\_Messages* (ou *locale/LC\_Messages* pour les systèmes Unix) et */usr/share/locale/* (systèmes Unix seulement).

La recherche s’effectue à partir de deux infixes : pour le français, il s’agit de **fr** et de **fr\_FR**. La seconde version est dite étendue et la première réduite. Il s’agit de nuances et de particularités entre des dialectes suivant le pays où est parlée la langue. Ainsi, le français peut-il être celui de France, mais aussi celui du Québec, de Belgique, du Bénin, du Burundi… La version réduite est traitée prioritairement.

La conversion des chaînes est effectuée grâce à la fonction *TranslateResourceStrings* dont le rôle est de balayer toutes les chaînes d’origine afin de les transformer selon le contenu du fichier **PO**.

Ce n’est qu’après un traitement réussi que la LCL est traduite elle aussi par la même fonction *TranslateResourceStrings*. Voilà pourquoi nous avions besoin de créer un fichier **PO** propre à notre fiche pour obtenir une traduction correcte de la chaîne ***&Yes*** qui est définie et utilisée par la LCL.

### Une quatrième solution

Il ressort de cette analyse qu’il existe une quatrième façon de traiter notre problème : en forçant la traduction de la LCL grâce à une portion de code, nous n’aurons pas besoin d’un fichier **PO** supplémentaire. En revanche, le code en sera un peu alourdi : il faudra modifier le corps du programme en contraignant ce dernier à une traduction explicite à partir du fichier *lclstrconsts.fr.po*, le tout en exploitant deux nouvelles unités (***gettext*** et ***translations***).

program project3;

{$mode objfpc}{$H+}

uses

{$IFDEF UNIX}{$IFDEF UseCThreads}

cthreads,

{$ENDIF}{$ENDIF}

Interfaces, // this includes the LCL widgetset

Forms, unit3

{ you can add units after this },

sysutils, // une unite ajoutée pour PathDelim

gettext, translations; // deux unités ajoutées

{$R \*.res}

procedure LCLTranslate;

var

PODirectory, Lang, FallbackLang: String;

begin

Lang := ''; // langue d’origine

FallbackLang := ''; // langue d’origine étendue

PODirectory := '.' + PathDelim + 'languages' + PathDelim; // répertoire de travail

GetLanguageIDs(Lang, FallbackLang); // récupération des descriptifs de la langue

TranslateUnitResourceStrings('LCLStrConsts',

PODirectory + 'lclstrconsts.fr.po', Lang, FallbackLang); // traduction

end;

begin

RequireDerivedFormResource := True;

LCLTranslate; // on ordonne la traduction

Application.Initialize;

Application.CreateForm(TForm1, Form1);

Application.Run;

end.

On notera que le délimiteur pour les chemins d’accès aux fichiers est traité grâce à la constante *PathDelim* définie en fonction du système d’exploitation en cours par ***sysutils***. En évitant de coder ce délimiteur en dur, on étend la portabilité du code.

Avec cette méthode, il est inutile d’activer l’option **i18n**. Le répertoire du fichier **PO** est fourni par la procédure *LCLTranslate* à partir de la variable *PODirectory*. En revanche, seule la LCL est traduite par ce biais : la traduction d’autres unités exige de compléter le code ou de revenir à la traduction *via* **i18n** qui est au bout du compte bien plus simple à mettre en œuvre.

## De l’anglais au français

### Préparation du programme souche

L’étape suivante va un peu compliquer le programme à traduire. Vous allez construire un projet plus ambitieux avec deux fiches et des textes à traduire.

* Créez un nouveau projet ;
* Dans *Projet → Options du projet → i18n*, cochez i18n et Créer/mettre à jour le fichier « .po » en enregistrant le fichier « .lfm » ;
* Modifiez la légende de la fiche (*Caption*) en la faisant passer de ***Form1*** à ***In English 5…***;
* Ajoutez un bouton à la fiche ;
* Passez sa propriété *AutoSize* de *False* à *True* afin que la taille du bouton s’adapte automatiquement à celle de sa légende ;
* Créez un gestionnaire d’événement *OnClick* pour ce bouton ;
* Tapez le code suivant pour ce gestionnaire :

implementation

{$R \*.lfm}

{ TForm1 }

resourcestring

RS\_Hello = 'Hello world !';

RS\_Bye = 'Goodbye cruel world !';

procedure TForm1.Button1Click(Sender: TObject);

// \*\*\* inversion de la légende du bouton 1 \*\*\*

begin

if Button1.Caption = RS\_Hello then

Button1.Caption := RS\_Bye

else

Button1.Caption := RS\_Hello;

end;

Remarquez que les chaînes ne sont elles aussi pas saisies en dur, c’est-à-dire qu’elles sont isolées dans une section particulière (*resourcestring*) qui indique qu’il s’agit de ressources qui feront l’objet d’un stockage particulier. Sans ce dernier, les traductions ne s’effectueront pas, les libellés des constantes de ressources servant d’index au traducteur.

* Créez aussi un gestionnaire d’événement *OnCreate* pour la fiche afin qu’une légende s’affiche correctement dès le lancement de l’application :

procedure TForm1.FormCreate(Sender: TObject);

// \*\*\* création de l'application \*\*\*

begin

Button1.Caption := RS\_Hello;

end;

* Ajoutez un second bouton à cette fiche ;
* Modifiez sa légende (*Caption*) de **Button2** à **New…** ;
* Créez un gestionnaire d’événement *OnClick* pour ce bouton, mais laissez-le vide pour le moment ;
* Cliquez sur *Nouvelle fiche* du menu *Fichier* ;
* Modifiez la légende (*Caption*) de cette nouvelle fiche de **Form2** à **New form**;
* Ajoutez un composant *TBitBtn* à cette fiche ;
* Modifiez sa propriété *Kind* de *bkCustom* à *bkClose* ;
* Ajoutez du texte à la propriété *Hint* de ce bouton : **Close the form** ;
* Passez sa propriété *ShowHint* de *False* à *True* afin de permettre l’affichage à l’exécution d’une bulle d’aide associée à ce bouton ;
* Dans *Projet → Options du projet →Fiches*, passez la fiche **Form2** de la colonne « créer les fiches automatiquement » à la colonne « fiches disponibles » avant de valider ce choix en cliquant sur OK ;
* Dans la partie *implementation* de la première fiche **Form1**, ajoutez une clause uses afin que la seconde fiche soit connue de la première :

uses

unit2 ;

* Retournez au gestionnaire *OnClick* du second bouton de la première fiche (**Form1**) et entrez le code suivant :

procedure TForm1.Button2Click(Sender: TObject);

// \*\*\* ouverture d'une nouvelle fiche \*\*\*

var

MyForm: TForm2;

begin

MyForm := TForm2.Create(Self); // on crée la fiche

try

MyForm.ShowModal; // on la montre (seule active

finally

MyForm.Close; // on libère la fiche

end;

end;

* Enregistrez le projet sous le nom *project5.lpr* ;
* Compilez et lancez l’application.

Vous disposez à présent d’une application un peu plus complexe que les précédentes, avec deux fiches dont une qui permet de faire surgir la seconde sous forme modale.

En dehors de sa relative complexité, cette application présente aussi la particularité d’être en anglais. L’objectif va évidemment être de la traduire le plus simplement possible en français.

### fichiers LRT et PO

Une première méthode consisterait à reprendre toutes les chaînes entrées et de les traduire. Si vous la choisissez, c’est que vous n’avez pas lu ce qui précédait !

La méthode la plus efficace va passer par la création d’un dossier *languages* dans lequel vous allez copier l’habituel fichier *lclstrconsts.fr.po* pour la traduction de la LCL , mais aussi le fraîchement créé *project5.po*.

Comme vous avez activé l’option **i18n** et l’enregistrement avec les fichiers **LFM**, Lazarus a créé automatiquement autant de fichiers **LRT** que d’unités et un unique fichier **PO** qui regroupe l’ensemble des chaînes à traduire.

En utilisant votre éditeur préféré, vous vous apercevrez que le fichier **unit1.lrt**, contient des paires de valeurs :

**TFORM1.CAPTION=In English 5...**

**TFORM1.BUTTON1.CAPTION=Button1**

**TFORM1.BUTTON2.CAPTION=New...**

Le fichier **unit2.lrt** est construit selon le même modèle :

**TFORM2.CAPTION=New form**

**TFORM2.BITBTN1.HINT=Close the form**

De son côté, le contenu de **project5.po,** un peu plus complexe, reprend les mêmes informations réparties sur trois lignes, accompagnées d’un en-tête et des chaînes de ressources incluses dans le code source :

msgid ""

msgstr "Content-Type: text/plain; charset=UTF-8"

#: tform1.button1.caption

msgid "Button1"

msgstr ""

#: tform1.button2.caption

msgid "New..."

msgstr ""

#: tform1.caption

msgid "In English 5..."

msgstr ""

#: tform2.bitbtn1.hint

msgid "Close the form"

msgstr ""

#: tform2.caption

msgid "New form"

msgstr ""

#: unit1.rs\_bye

msgid "Goodbye cruel world !"

msgstr ""

#: unit1.rs\_hello

msgid "Hello world !"


msgstr ""

L’en-tête précise que le type de caractères utilisé est *UTF-8* pour la prise en compte des jeux de caractères différents suivant les langues. Cet en-tête contiendra plus tard un identificateur de la langue de traduction. Quant aux triplets de valeurs, ils comportent tous une troisième ligne réduite au code **msgstr** (pour *message string*) suivi d’une chaîne vide **""**. C’est cette chaîne vide qui contiendra la traduction désirée. Enfin, la première ligne de ces triplets correspond à un repère dans le code source ou dans le fichier **LFM**.


Même si la traduction peut se faire manuellement, l’utilisation d’outils spécialisés dans le traitement des fichiers **PO** est vivement recommandée : non seulement ils évitent bien des erreurs, mais ils fournissent aussi des outils d’édition et souvent des propositions de traduction qui s’appuient sur vos traductions et celles présentes sur Internet.

Pour Windows et Linux, un éditeur comme **poEdit** (gratuit dans sa version standard) est bien adapté. Il en existe d’autres parmi lesquels vous trouverez certainement celui qui vous convient le mieux.

Avant de traduire, le fichier souche doit être préservé : faites-en une copie dans le répertoire *languages* et rebaptisez-le *project5.fr.po*. L’infixe *fr* est celui qui indique qu’il s’agit de la traduction française : sans lui, il faudra préciser la langue de traduction. **poEdit** reconnaît immédiatement cet infixe et présente le fichier sous cette forme :



Proposez la traduction suivante :



Après avoir enregistré votre travail de traduction, vous pouvez éditer le fichier modifié :

**msgid ""**

**msgstr ""**

**"Content-Type: text/plain; charset=UTF-8\n"**

**"Project-Id-Version: \n"**

**"POT-Creation-Date: \n"**

**"PO-Revision-Date: \n"**

**"Last-Translator: \n"**

**"Language-Team: \n"**

**"MIME-Version: 1.0\n"**

**"Content-Transfer-Encoding: 8bit\n"**

**"Language: fr\n"**

**"X-Generator: Poedit 1.7.5\n"**

**#: tform1.button1.caption**

**msgid "Button1"**

**msgstr "Bouton1"**

**#: tform1.button2.caption**

**msgid "New..."**

**msgstr "Nouveau..."**

**#: tform1.caption**

**msgid "In English 5..."**

**msgstr "En français..."**

**#: tform2.bitbtn1.hint**

**msgid "Close the form"**

**msgstr "Fermer la fiche"**

**#: tform2.caption**

**msgid "New form"**

**msgstr "Nouvelle fiche"**

**#: unit1.rs\_bye**

**msgid "Goodbye cruel world !"**

**msgstr "Adieu, monde cruel !"**

**#: unit1.rs\_hello**

**msgid "Hello world !"**

**msgstr "Bonjour le monde !"**

En dehors de l’en-tête qui a pris de l’ampleur afin de préciser si nécessaire la langue de traduction, l’identité du traducteur et/ou de son équipe, les dates de création et de modification et l’outil de traduction utilisé, vous remarquerez surtout que les troisièmes lignes déjà mentionnées de chaque triplet contiennent à présent la traduction proposée pour la chaîne originale correspondante.

### Traduction automatique complète

L’unité ***DefaultTranslator*** dispose de tout ce qui lui est nécessaire pour travailler :

* Un répertoire *languages* pour y chercher les fichiers de traduction ;
* Des fichiers **PO** qui contiennent les repères des chaînes à modifier ainsi que les couples de chaînes langue d’origine/langue de traduction.

Vous avez là l’explication de l’absence de traduction des chaînes codées en dur : il manque à l’unité les moyens de savoir où les situer sans ambiguïté.

En ajoutant tout simplement le nom de cette unité dans la clause uses du programme principal, vous obtenez… un programme en français !

program project5;

{$mode objfpc}{$H+}

uses

{$IFDEF UNIX}{$IFDEF UseCThreads}

cthreads,

{$ENDIF}{$ENDIF}

Interfaces, // this includes the LCL widgetset

Forms, Unit1, Unit2,

DefaultTranslator; // en français !

{$R \*.res}

begin

RequireDerivedFormResource := True;

Application.Initialize;

Application.CreateForm(TForm1, Form1);

Application.Run;

end.

## Encore plus loin : de l’anglais au choix de la langue

Un degré de complexité sera franchi si vous souhaitez laisser le choix de la langue à l’utilisateur de votre programme.